##################################################################
## 
##    QtVision configure script
##    George Staikos <staikos@kde.org>
##
##################################################################

dnl ---------------------------------------------------------------------
dnl Linux DVB-S support
    have_dvbs=no
    AC_CHECK_HEADER(linux/dvb/frontend.h,
		     AC_DEFINE(HAVE_DVBS, 1, [If we have Linux DVB-S])
		     have_dvbs=yes
		     ,,[#include <linux/dvb/frontend.h>])

dnl ---------------------------------------------------------------------
dnl OpenGL
    KDE_CHECK_LIB(GL, glAccum,
	GL_LIBS="-lGL $GL_LIBS",,
	-lm -L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)
    KDE_CHECK_LIB(GLU, gluBeginCurve,
	GL_LIBS="-lGLU $GL_LIBS",,
	-lm -lGL -L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)
    KDE_CHECK_LIB(GLX, glXChooseVisual,
	GL_LIBS="-lGLX $GL_LIBS",,
	-L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)
    KDE_CHECK_LIB(glut, glXChooseVisual,
	,,
	-lm -lGL -lGLU -L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)
    KDE_CHECK_LIB(glut, glutInit,
	,,
	-lm -lGL -lGLU -L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)

dnl ---------------------------------------------------------------------
dnl XVideo extension
    KDE_CHECK_LIB(Xv, XvQueryExtension, 
        QTVISION_LIBS="-lXv $QTVISION_LIBS",, 
        -L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)

dnl ---------------------------------------------------------------------
dnl XVideo Motion Compensation extension
    KDE_CHECK_LIB(XvMC, XvMCQueryExtension, 
        QTVISION_LIBS="-lXvMC $QTVISION_LIBS",, 
        -L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)


dnl ---------------------------------------------------------------------
dnl Other X extensions

    KDE_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension, 
        QTVISION_LIBS="-lXxf86dga $QTVISION_LIBS",,
        -L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)
    KDE_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
        QTVISION_LIBS="-lXxf86vm $QTVISION_LIBS",,
        -L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)
dnl Check for dpms - we check for the existence of the header, because in XFree 4.x
dnl DPMSQueryExtension is included in Xlib
    have_xdpms=no
    AC_CHECK_HEADER(X11/extensions/dpms.h,
		     AC_DEFINE(HAVE_XDPMS, 1, [If we have xdpms])
		     have_xdpms=yes
		     ,,[#include <X11/Xlib.h>])
    have_xshm=no
    AC_CHECK_HEADER(X11/extensions/XShm.h,
		     AC_DEFINE(HAVE_XSHM, 1, [If we have xshm])
		     have_xshm=yes
		     ,,[#include <X11/Xlib.h>])
    KDE_CHECK_LIB(Xdpms, DPMSQueryExtension,
        QTVISION_LIBS="-lXdpms $QTVISION_LIBS",,
        -L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)

    KDE_CHECK_LIB(Xinerama, XineramaQueryExtension,
        QTVISION_LIBS="-lXinerama $QTVISION_LIBS",,
        -L/usr/X11R6/lib $X_LIBS $X_PRE_LIBS -lXext -lX11 $X_EXTRA_LIBS)


if test $ac_cv_lib_glut_glXChooseVisual = yes ||
   test $ac_cv_lib_glut_glutInit = yes; then
  GL_LIBS="-lglut $GL_LIBS"
fi

AC_SUBST(QTVISION_LIBS)
AC_SUBST(GL_LIBS)

if test $ac_cv_lib_Xxf86dga_XF86DGAQueryExtension = yes; then
  AC_DEFINE(HAVE_XDGA, 1, [If we have the X11 DGA extension])
fi

if test $ac_cv_lib_Xv_XvQueryExtension = yes; then
  AC_DEFINE(HAVE_LIBXV, 1, [If we have the XVideo extension])
fi

if test $ac_cv_lib_XvMC_XvMCQueryExtension = yes; then
  AC_DEFINE(HAVE_LIBXVMC, 1, [If we have the XVideo Motion Compensation extension])
fi

if test $ac_cv_lib_GL_glAccum = yes; then
  AC_DEFINE(HAVE_GL, 1, [If we have OpenGL])
fi

if test $ac_cv_lib_GLU_gluBeginCurve = yes; then
  AC_DEFINE(HAVE_GLU, 1, [If we have OpenGL GLU])
fi

if test $ac_cv_lib_GLX_glXChooseVisual = yes; then
  AC_DEFINE(HAVE_GLX, 1, [If we have OpenGL GLX])
fi

if test $ac_cv_lib_glut_glXChooseVisual = yes; then
  AC_DEFINE(HAVE_GLUT_GLX, 1, [If we have OpenGL GLX in glut])
fi

if test $ac_cv_lib_glut_glutInit = yes; then
  AC_DEFINE(HAVE_GLUT, 1, [If we have OpenGL glut])
fi

dnl ---------------------------------------------------------------------
dnl Check for LIRC client support

have_lirc=yes
KDE_CHECK_LIB(lirc_client,lirc_init,,have_lirc=no)
if test "$have_lirc" = "yes"; then
	KDE_CHECK_HEADER(lirc/lirc_client.h,,have_lirc=no)
fi

if test "$have_lirc" = "yes"; then
	AC_DEFINE(HAVE_LIRC, 1, [If we have lirc client library])
	LIB_LIRC="-llirc_client"
	AC_SUBST(LIB_LIRC)
fi